1

次のファイルを xsltprocessor の入力として使用:

mylibrary.xml :

<library>  
   <book isbn="1"/>    
   <book isbn="3"/>
   <book isbn="5"/>
</library>

そして、これを使用することができます: bookreference.xml : 

<reference>  
    <book isbn="1">  
        <category>SF</category>  
    </book>  
    <book isbn="2">  
        <category>SF</category>  
    </book>  
    <book isbn="3">  
        <category>SF</category>  
    </book>  
    <book isbn="4">  
        <category>Comedy</category>  
    </book>  
    <book isbn="5">  
        <category>Comedy</category>  
    </book>
</reference>

xslt 1-0 を使用して、mylibrary の groupby カテゴリで取得した本の数を取得したいと考えています。

必要な出力:

SF : 2 book(s) 
Comedy : 1 book(s)

これは、「ソースとして 2 つの異なる XML ファイルを使用する場合のグループ化」で説明されている Martin Honnen メソッドを使用して作成した xsl です。、私は問題を解決すると思いますが、まだ検証しておらず、おそらく誰かがより良い解決策を持っています.

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl"
  version="1.0">

<xsl:output method="xml" indent="yes"/>
<xsl:key name="book-by-category" match="book" use="category"/>

<xsl:param name="bookref" select="'bookreference.xml'"/>
<xsl:variable name="doc" select="document($bookref)/reference"/>

<xsl:variable name="rtf">
    <xsl:apply-templates select="//library" mode="merge"/>
</xsl:variable>

<xsl:template match="library" mode="merge">
    <xsl:element name="mybookcat">
    <xsl:for-each select="book">
        <xsl:variable name="isbn" select="@isbn"/>
        <xsl:element name="book">
        <xsl:attribute name="isbn"><xsl:value-of select="$isbn"/></xsl:attribute>
        <xsl:for-each select="$doc/book[@isbn=$isbn]">
            <xsl:element name="category">
                <xsl:value-of select="./category"/>
            </xsl:element>
        </xsl:for-each>
        </xsl:element>
    </xsl:for-each>
    </xsl:element>
</xsl:template>     

<xsl:template match="/">
    <xsl:apply-templates select="exsl:node-set($rtf)/mybookcat"/>
</xsl:template>

<xsl:template match="mybookcat">
<xsl:for-each select="book[count(. | key('book-by-category',category)[1]) = 1]"> 
    <xsl:sort select="category"/> 
    <xsl:value-of select="category" /><xsl:text> : </xsl:text>
    <xsl:variable name="current-cat" select="key('book-by-category', category)"/>
    <xsl:value-of select="count($current-cat)"/><xsl:text> book(s)
</xsl:text>
    <xsl:for-each select="key('book-by-category', category)">
        <xsl:sort select="@isbn" data-type="number" />
        <xsl:value-of select="@isbn" /><xsl:text>
</xsl:text>            
    </xsl:for-each>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
4

1 に答える 1

2

これは、「ソースとして 2 つの異なる XML ファイルを使用する場合のグループ化」で説明されている Martin Honnen メソッドを使用して作成した xsl です。、問題は解決したと思いますが、まだ検証していません。おそらく誰かがより良い解決策を持っています

.

以下は、拡張関数または を使用しない、より単純な XSLT 1.0 ソリューションですxsl:for-each。

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:key name="kBookByCat" match="book"
          use="category"/>

     <xsl:variable name="vRef" select=
     "document('file:///c:/temp/delete/reference.xml')"/>

     <xsl:variable name="vMyIsbns" select="/*/*/@isbn"/>

     <xsl:variable name="vResult">
      <xsl:apply-templates select="$vRef/*"/>
     </xsl:variable>

     <xsl:template match="/">
      <xsl:copy-of select="$vResult"/>
     </xsl:template>

     <xsl:template match=
      "book[generate-id()
           =
            generate-id(key('kBookByCat', category)[1])
            ]
      ">
         <xsl:variable name="vBooksinCat" select=
              "key('kBookByCat', category)"/>

         <xsl:value-of select="category"/> : <xsl:text/>
         <xsl:value-of select="count($vBooksinCat[@isbn=$vMyIsbns])"/>
         <xsl:text> book(s)&#xA;</xsl:text>
     </xsl:template>
     <xsl:template match="text()"/>
</xsl:stylesheet>

に含まれる提供された XML ドキュメントに適用すると、次のようになりMyLibrary.xmlます。

<library>
    <book isbn="1"/>
    <book isbn="3"/>
    <book isbn="5"/>
</library>

この提供された XML ドキュメントをファイルに含めるC:\temp\delete\reference.xml:

<reference>
    <book isbn="1">
        <category>SF</category>
    </book>
    <book isbn="2">
        <category>SF</category>
    </book>
    <book isbn="3">
        <category>SF</category>
    </book>
    <book isbn="4">
        <category>Comedy</category>
    </book>
    <book isbn="5">
        <category>Comedy</category>
    </book>
</reference>

必要な正しい結果が生成されます。

SF : 2 book(s)
Comedy : 1 book(s)

Ⅱ．XSLT 2.0 ソリューション:

2 番目のドキュメントに依存するようにキーを定義できるため、これは少し単純です。

<xsl:stylesheet version="2.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:key name="kBookByCat" match="book[@isbn = $vMyIsbns]"
          use="category"/>

     <xsl:variable name="vRef" select=
     "document('file:///c:/temp/delete/reference.xml')"/>

     <xsl:variable name="vMyIsbns" select="/*/*/@isbn"/>

     <xsl:variable name="vResult">
      <xsl:apply-templates select="$vRef/*"/>
     </xsl:variable>

     <xsl:template match="/">
      <xsl:copy-of select="$vResult"/>
     </xsl:template>

     <xsl:template match=
      "book[generate-id()
           =
            generate-id(key('kBookByCat', category)[1])
            ]
      ">
         <xsl:variable name="vBooksinCat" select=
              "key('kBookByCat', category)"/>

         <xsl:value-of select="category"/> : <xsl:text/>
         <xsl:value-of select="count($vBooksinCat)"/>
         <xsl:text> book(s)&#xA;</xsl:text>
     </xsl:template>
     <xsl:template match="text()"/>
</xsl:stylesheet>
于 2011-12-01T03:29:59.400 に答える