1

次の構造を持つ XML ドキュメントを変換する必要があります。

<NODEA d="8" m="1" xxxxx="WWWWWWWWWWWWWW"/> 
<NODEA d="16" m="1" xxxxx="somethingelse"/> 

<NODEB d="1" m="1" yyyyy="xx"/> 
<NODEB d="2" m="1" yyyyy="xx"/> 
<NODEB d="3" m="1" yyyyy="yy"/> 
<NODEB d="4" m="1" yyyyy="zz"/> 
<NODEB d="5" m="1" yyyyy="aa"/> 
<NODEB d="6" m="1" yyyyy="ss"/> 
<NODEB d="7" m="1" yyyyy="33"/> 
<NODEB d="8" m="1" yyyyy="AAAAAAAAAAAAA"/> 
<NODEB d="9" m="1" yyyyy="qq"/>   etc

xsltで、属性「d」が等しいときに2つのノードをマージしようとします

<NewNode>
   <d>8</d>
   <m>1</m>
   <xxxxx>WWWWWWWWWWWWWW</xxxxx>
   <yyyyy>AAAAAAAAAAAAA</yyyyy>
</NewNode>

こうすることで

<xsl:template match="NODEB">
<xsl:element name="NewNode"> 
    <xsl:apply-templates select="@d" />
    <xsl:apply-templates select="@m" />
    <xsl:apply-templates select="@yyyyy" />

    <xsl:element name="xxxxx" >
        <xsl:for-each select="//NODEA">
            <xsl:if test=".@d eq @d">
                <xsl:value-of select=".@xxxxx" />
            </xsl:if>
        </xsl:for-each>          
    </xsl:element>
</xsl:element>

したがって、ifステートメントは明らかに機能しませんが、それ以外の場合はどうすればよいですか?

4

2 に答える 2

2

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kElemByD" match="*" use="@d"/>

 <xsl:template match="node()|@*" priority="-1">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template priority="1" match=
  "*[generate-id()
    =
     generate-id(key('kElemByD', @d)[2])
    ]
  ">
  <newNode>
   <xsl:copy-of select="key('kElemByD', @d)/@*"/>
  </newNode>
 </xsl:template>

 <xsl:template match=
  "*[count(key('kElemByD', @d)) > 1]"/>
</xsl:stylesheet>

提供された XML に適用された場合(整形式の XML ドキュメントになるようにトップ要素にラップされます):

<t>
    <NODEA d="8" m="1" xxxxx="WWWWWWWWWWWWWW"/>
    <NODEA d="16" m="1" xxxxx="somethingelse"/>

    <NODEB d="1" m="1" yyyyy="xx"/>
    <NODEB d="2" m="1" yyyyy="xx"/>
    <NODEB d="3" m="1" yyyyy="yy"/>
    <NODEB d="4" m="1" yyyyy="zz"/>
    <NODEB d="5" m="1" yyyyy="aa"/>
    <NODEB d="6" m="1" yyyyy="ss"/>
    <NODEB d="7" m="1" yyyyy="33"/>
    <NODEB d="8" m="1" yyyyy="AAAAAAAAAAAAA"/>
    <NODEB d="9" m="1" yyyyy="qq"/>
</t>

必要な正しい結果が生成されます。

<t>
   <NODEA d="16" m="1" xxxxx="somethingelse"/>
   <NODEB d="1" m="1" yyyyy="xx"/>
   <NODEB d="2" m="1" yyyyy="xx"/>
   <NODEB d="3" m="1" yyyyy="yy"/>
   <NODEB d="4" m="1" yyyyy="zz"/>
   <NODEB d="5" m="1" yyyyy="aa"/>
   <NODEB d="6" m="1" yyyyy="ss"/>
   <NODEB d="7" m="1" yyyyy="33"/>
   <newNode d="8" m="1" xxxxx="WWWWWWWWWWWWWW" yyyyy="AAAAAAAAAAAAA"/>
   <NODEB d="9" m="1" yyyyy="qq"/>
</t>

説明: グループ化のためのMuenchian メソッド。

于 2011-12-27T17:44:21.937 に答える
0

@Dimitreよりも少しエレガントではありませんが、2つのfor-eachを使用できます:)

編集済み

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        version="1.0">
        <xsl:template match="/">
            <xsl:for-each select="//NODEA">
                <xsl:variable name="nodea" select="."/>
                <xsl:variable name="d" select="./@d"/>

                <!-- The d should match only then create New Node -->
                <xsl:for-each select="//NODEB[@d = $d]">
                    <xsl:variable name="nodeb" select="." />
                    <NewNode>
                        <d><xsl:value-of select="$d"/></d>
                        <m><xsl:value-of select="$nodea/@m"/></m>
                        <xxxxx><xsl:value-of select="$nodea/@xxxxx"/></xxxxx>
                        <yyyyy><xsl:value-of select="$nodeb/@yyyyy"/></yyyyy>
                    </NewNode>
                    </xsl:for-each>
                </xsl:for-each>
        </xsl:template>
    </xsl:stylesheet>

必要な出力を生成するもの

        <NewNode>
            <d>8</d>
            <m>1</m>
            <xxxxx>WWWWWWWWWWWWWW</xxxxx>
            <yyyyy>AAAAAAAAAAAAA</yyyyy>
        </NewNode>
于 2011-12-28T17:22:33.490 に答える