3

Delphi 2006 で動作する次の関数がありますが、Delphi XE2 では、処理時にアクセス違反エラーまたは特権命令エラーが発生しますRET。

function Q_TrimChar(const S: string; Ch: Char): string;
asm
        PUSH    ESI
        MOV     ESI,ECX
        TEST    EAX,EAX
        JE      @@qt
        MOV     ECX,[EAX-4]
        TEST    ECX,ECX
        JE      @@qt
        PUSH    EBX
        PUSH    EDI
        MOV     EBX,EAX
        MOV     EDI,EDX
        XOR     EDX,EDX
        MOV     EAX,ESI
        CALL    System.@LStrFromPCharLen
        MOV     EDX,EDI
        MOV     ECX,[EBX-4]
@@lp1:  CMP     DL,BYTE PTR [EBX]
        JNE     @@ex1
        INC     EBX
        DEC     ECX
        JNE     @@lp1
        MOV     EDX,[ESI]
        JMP     @@wq
@@ex1:  DEC     ECX
@@lp2:  CMP     DL,BYTE PTR [EBX+ECX]
        JNE     @@ex2
        DEC     ECX
        JMP     @@lp2
@@ex2:  MOV     EDI,[ESI]
        LEA     EDX,[EDI+ECX+1]
@@lp3:  MOV     AL,BYTE PTR [EBX+ECX]
        MOV     BYTE PTR [EDI+ECX],AL
        DEC     ECX
        JNS     @@lp3
@@wq:   MOV     EAX,[ESI]
        MOV     BYTE PTR [EDX],0
        SUB     EDX,EAX
        MOV     [EAX-4],EDX
        POP     EDI
        POP     EBX
        POP     ESI
        RET
@@qt:   MOV     EAX,ESI
        CALL    System.@LStrClr
        POP     ESI
end;

組み立てがよくわかりません。何が問題ですか？

4

2 に答える 2

17

これを Pascal で単純にコーディングするという David の提案に完全に同意し、その回答に賛成しました。プロファイリングでこれが真のボトルネックであることが示されない限り、ASM は本当に必要ありません。ここに 2 つのバージョンがあります。前者の方が読みやすいですが、後者の方が効率的です。

function Q_TrimChar(const S: string; Ch: Char): string;
begin
  result := S;
  while (result <> '') and (result[1] = Ch) do Delete(Result, 1, 1);
  while (result <> '') and (result[Length(Result)] = Ch) do Delete(Result, Length(Result), 1);
end;

function Q_TrimChar(const S: string; Ch: Char): string;
var
  First, Last : integer;
begin
  First := 1;
  Last := Length(S);
  while (First < Last) and (S[First] = Ch) do inc(First);
  while (Last >= First) and (S[Last] = Ch) do Dec(Last);
  Result := copy(S, First, Last-First+1);
end;
于 2012-02-17T02:13:16.257 に答える
6

Delphi 2006 では、1 バイトの ANSI 文字が使用されてstringいます。Delphi 2009 以降では、2 バイトの Unicode 文字が使用されます。この関数は、両方のコンパイラで動作する可能性はありません。AnsiStringCharAnsiChar

AnsiString と AnsiChar を使用する標準的なハックでさえ機能しません。おそらく、この関数が RTL 実装に関して行った仮定は、最新の Delphi では有効ではなくなりました。

この関数を Pascal で書き直して、コンパイラーに任せます。これは、現在の問題を解決するための最速の方法であるだけでなく、64 ビット コンパイルに取り組むことを選択した場合でも、64 ビット コンパイルのハードルを乗り越えることができます。

于 2012-02-17T00:45:58.033 に答える