10

次の構成のWCFサービスがあります。

<services>
  <service name="MyService" behaviorConfiguration="MyServiceBehavior">
    <endpoint 
      binding="basicHttpBinding"  
      contract="IMyService" />
    <host>
      <baseAddresses>
        <add baseAddress="http://localhost:8001/MyService" />
      </baseAddresses>
    </host>
  </service>
</services>

<behaviors>
  <serviceBehaviors>
    <behavior name="MyServiceBehavior">
      <serviceMetadata httpGetEnabled="True" />
    </behavior>
  </serviceBehaviors>
</behaviors>

このスクリプトはそれを呼び出すことになっています：

Option Explicit

Dim soapClient
Dim serviceUri
Dim serviceName
Dim portName
Dim result

serviceUri = "http://localhost:8001/MyService"
serviceName = "MyService"
portName = "BasicHttpBinding_IMyService"

Set soapClient = CreateObject("MSSOAP.soapClient")
soapClient.ClientProperty("ServerHTTPRequest") = True
soapClient.mssoapinit serviceUri & "?WSDL", serviceName, portName

スクリプトを実行すると、次のエラーが表示されます。

クライアント：WSDLReader：WSDLファイルの分析に失敗しましたHRESULT = 0x8 0004005-WSDLReader：サービスの初期化に失敗しましたHRESULT = 0x80004005-WSDLサービス：サービスMyServiceのポートの初期化に失敗しましたHRESULT = 0x80004005-WSDLPort：ポートのバインディング情報の分析に失敗しましたBasicHttpBinding_IMyServiceに失敗しましたHRESULT = 0x80004005-WSDLPort：ポートBasicHttpBinding_IMyServiceの操作を初期化できませんでしたHRESULT = 0x8000 4005-WSDLOperation：操作// def：portType [@ name = "IMyService"] / def：operation [@ name="MyMethod"]は初期化できませんでしたポートタイプセクションにありますHRESULT=0x80004005

何が問題になっていますか？助けてください。

編集：

Cheeso、答えてくれてありがとう。MSSOAPの問題は、生成されたWSDLファイルにすべてのxsdスキーマをインラインで含める必要があることです。WCFはデフォルトではそれを行いません。

4

1 に答える 1

15

MSSOAPは使用しないでください。過去3、4年間、現在はサポートされていないと思います。MSXMLの一部であり、サポートされ、継続して維持されているXmlHttpの使用を検討してください。SOAPエンベロープを手動で作成する必要があります。しかし、この方法の方が信頼性が高くなります。

サンプルコード

' URL to the WCF service'
url= "http://server:port/Wcf.Service.Address"

Dim requestDoc
Set requestDoc = WScript.CreateObject("MSXML2.DOMDocument.6.0")

Dim root
Set root = requestDoc.createNode(1, "Envelope", "http://schemas.xmlsoap.org/soap/envelope/")
requestDoc.appendChild root

Dim nodeBody
Set nodeBody = requestDoc.createNode(1, "Body", "http://schemas.xmlsoap.org/soap/envelope/")
root.appendChild nodeBody

Dim nodeOp
Set nodeOp = requestDoc.createNode(1, "Register", "urn:Your.Namespace.Here")
nodeBody.appendChild nodeOp

Dim nodeRequest
Set nodeRequest = requestDoc.createNode(1, "request", "urn:Your.Namespace.Here")
'content of the request will vary depending on the WCF Service.'
' This one takes just a plain string. '
nodeRequest.text = "Hello from a VBScript client."

nodeOp.appendChild nodeRequest

Set nodeRequest = Nothing
Set nodeOp = Nothing
Set nodeBody = Nothing
Set root = Nothing


'the request will look like this:'
'       <s:Envelope xmlns:s='http://schemas.xmlsoap.org/soap/envelope/'> '
'         <s:Body> '
'           <Register xmlns='urn:Your.Namespace.Here'> '
'               <request>hello from a VBScript client.</request> '
'           </Register> '
'         </s:Body> '
'       </s:Envelope>'


WSCript.Echo  "sending request " & vbcrlf & requestDoc.xml


dim xmlhttp

set xmlhttp = WScript.CreateObject("MSXML2.ServerXMLHTTP.6.0")
' set the proxy as necessary and desired '
xmlhttp.setProxy 2, "http://localhost:8888"
xmlhttp.Open "POST", url, False
xmlhttp.setRequestHeader "Content-Type", "text/xml"
' set SOAPAction as appropriate for the operation '
xmlhttp.setRequestHeader "SOAPAction", "urn:Set.As.Appropriate"
xmlhttp.send requestDoc.xml

WScript.Echo vbcrlf & "Raw XML response:" & vbcrlf 
WSCript.Echo  xmlhttp.responseXML.xml

dim response
set response= xmlhttp.responseXML
'the response is an MSXML2.DOMDocument.6.0' 
'party on the response here - XPath, walk the DOM, etc. '

参考： MSXMLのバージョンを選択する方法については、which-version-of-msxml-should-i-useを参照してください。

于 2009-06-03T19:48:28.540 に答える