5

私は時々次のようなハッシュにアクセスします:

if(exists $ids{$name}){
    $id = $ids{$name};
}

それは良い習慣ですか？実際には 1 つを実行する必要があるのに 2 つのルックアップが含まれていることを少し心配しています。存在を確認して値を割り当てるより良い方法はありますか?

4

6 に答える 6

10

で確認することによりexists、自動生存を防ぎます。Autovivificationを参照してください：それは何ですか、なぜ私は気にしますか？。

更新： trendelsが以下で指摘しているように、投稿した例では自動生存は機能しません。実際のコードにはマルチレベルのハッシュが含まれていると思います。

これがイラストです：

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;

my (%hash, $x);

if ( exists $hash{test}->{vivify} ) {
    $x = $hash{test}->{vivify}->{now};
}

print Dumper \%hash;

$x = $hash{test}->{vivify}->{now};

print Dumper \%hash;

__END__


C:\Temp> t
$VAR1 = {
    'test' => {}
};
$VAR1 = {
    'test' => {
        'vivify' => {}
    }
};
于 2009-06-10T18:42:19.183 に答える
2

Hash::Utilの lock_keys をハッシュに適用できます。次に、評価内で割り当てを実行します。

#!/usr/bin/perl
use Hash::Util qw/lock_keys/;

my %a = (
    1 => 'one',
    2 => 'two'
);

lock_keys(%a);

eval {$val = $a{2}};     # this assignment completes
eval {$val = $a{3}};     # this assignment aborts
print "val=$val\n";      # has value 'two'
于 2009-06-11T02:02:55.453 に答える
1

この場合、パフォーマンスは重要ではありません。「Devel::NYTProf」を参照してください。しかし、あなたの質問に答えるには：

ハッシュの値が存在しない場合、「存在する」は非常に高速です 

if(exists $ids{$name}){
    $id = $ids{$name};
}

存在する場合は、2 回目の検索が行われます。値が存在する可能性が高い場合は、ルックアップを 1 回だけ行うよりも高速になります

$id = $ids{$name};
if($id){
    #....
}

perl メーリング リストのこの littel ベンチマークを参照してください。

#!/usr/bin/perl -w
use strict;
use Benchmark qw( timethese );

use vars qw( %hash );
@hash{ 'A' .. 'Z', 'a' .. 'z' } = (1) x 52;

my $key = 'xx';
timethese 10000000, {
        'defined' => sub {
                if (defined $hash{$key}) { my $x = $hash{$key}; return $x; };
                return 0;
        },
        'defined_smart' => sub {
                my $x = $hash{$key};
                if (defined $x) {
                        return $x;
                };
                return 0;
        },
        'exists' => sub {
                if (exists $hash{$key}) { my $x = $hash{$key}; return $x; };
                return 0;
        },
        'as is' => sub {
                if ($hash{$key}) { my $x = $hash{$key}; return $x; };
                return 0;
        },
        'as is_smart' => sub {
                my $x = $hash{$key};
                if ($x) { return $x; };
                return 0;
        },

};

存在しないキー ('xx') を使用すると、'exists' が勝者となります。

Benchmark: timing 10000000 iterations of as is, as is_smart, defined, defined_smart, exists...
     as is:  1 wallclock secs ( 1.52 usr +  0.00 sys =  1.52 CPU) @ 6578947.37/s (n=10000000)
as is_smart:  3 wallclock secs ( 2.67 usr +  0.00 sys =  2.67 CPU) @ 3745318.35/s (n=10000000)
   defined:  3 wallclock secs ( 1.53 usr +  0.00 sys =  1.53 CPU) @ 6535947.71/s (n=10000000)
defined_smart:  3 wallclock secs ( 2.17 usr +  0.00 sys =  2.17 CPU) @ 4608294.93/s (n=10000000)
    exists:  1 wallclock secs ( 1.33 usr +  0.00 sys =  1.33 CPU) @ 7518796.99/s (n=10000000)

存在する key('x') を使用すると、'as is_smart' が勝者であることが示されます。

Benchmark: timing 10000000 iterations of as is, as is_smart, defined, defined_smart, exists...
     as is:  3 wallclock secs ( 2.76 usr +  0.00 sys =  2.76 CPU) @ 3623188.41/s (n=10000000)
as is_smart:  3 wallclock secs ( 1.81 usr +  0.00 sys =  1.81 CPU) @ 5524861.88/s (n=10000000)
   defined:  3 wallclock secs ( 3.42 usr +  0.00 sys =  3.42 CPU) @ 2923976.61/s (n=10000000)
defined_smart:  2 wallclock secs ( 2.32 usr +  0.00 sys =  2.32 CPU) @ 4310344.83/s (n=10000000)
    exists:  3 wallclock secs ( 2.83 usr +  0.00 sys =  2.83 CPU) @ 3533568.90/s (n=10000000)
于 2013-08-20T14:48:02.917 に答える
1

次のように 1 回のルックアップで実行できます。

$tmp = $ids{$name};
$id = $tmp if (defined $tmp);

ただし、それがボトルネックであることがわからない限り、気にしません。

于 2009-06-10T18:34:09.247 に答える
0

高性能が必要な場合は、セットとしてハッシュを作成するときにこのイディオムを作成することに慣れています。

my %h;
for my $key (@some_vals) {
  ...
  $h{$key} = undef unless exists $h{$key};
  ...
}

return keys %h;

このコードは、一般的に使用されているものよりも少し高速です$h{$key}++。exists無駄な割り当てをundef回避し、値の割り当てを回避します。あなたにとっての最良の答えは：それをベンチマークすることです！私はそれexists $ids{$name}がより少し速いと思います、$id=$ids{$name}そしてあなたが大きなミス率を持っているならば、あなたのバージョンが存在するのは割り当てとその後のテストよりも速いかもしれません。

たとえば、高速セットの交差が必要な場合は、次のように記述します。

sub intersect {
  my $h;
  @$h{@{shift()}} = ();
  my $i;
  for (@_) {
    return unless %$h;
    $i = {};
    @$i{grep exists $h->{$_}, @$_} = ();
    $h = $i;
  }
  return keys %$h;
}
于 2009-06-11T09:44:14.377 に答える
0

マルチレベルハッシュでない場合は、次のように実行できます。

$id = $ids{$name} || 'foo';

または、$ idにすでに値がある場合：

$id ||= $ids{$name};

ここで、「foo」はデフォルト値またはフォールスルー値です。マルチレベルのハッシュの場合は、「exists」を使用して、スレッドで前述した自動生存を回避するか、自動生存が問題にならない場合は使用しないでください。

于 2009-06-11T01:17:54.437 に答える