10

ビットマップファイルのさまざまな色の量を視覚化したい。

私のデータセットは次のようになります。

1 163073164
4 185122087
3 255242000
8 255255255
3 000162232
1 181230029
1 127127127
1 136000021
3 200191231

gnu plotヒストグラムスタイルを使用して、各カラーバーを独自の色で描画したいと思います。

「lc変数」を使って試してみましたが、うまくいきません。:-(

今までの私のGNUPLOTスクリプト：

set style data histograms 
set boxwidth 1
set grid
set style histogram cluster gap 0  
set style fill solid 1.0 border -1
set yrange [0:*]
set xrange [0:*]
set xtics border in scale 0,10  nomirror rotate by -45  offset character 0, 0, 0 left
plot "histo.dat" using 1:xticlabels(2) lc variable no title
#EOF

このエラーメッセージが表示されます：

gnuplot> plot "histo.dat" using 1:xticlabels(2) lc variable no title
                                              ^
         "histo.plt", line 9: Bad data on line 1

誰かが私にヒントや正しいコマンドを教えてもらえますか？

よろしくロバート

4

2 に答える 2

22

良い質問です。boxes最初に使用していたスタイルとは対照的に、スタイルを使用して機能させることができましたhistogram。私はそれがあまり大きな違いを生むべきではないと思います：

set boxwidth 1
set grid
set style fill solid 1.0 border -1
set yrange [0:*]
set xrange [-.5:*]
set xtics border in scale 0,10  nomirror rotate by -45  
plot "histo.dat" using ($0):1:($0):xticlabels(2) w boxes lc variable notitle
                        #^boxes centered on 0,1,2,3,....
                           #^data column
                              #^ linecolor column.  first box has linecolor corresponding to ls 0, second box has linecolor corresponding to ls 1, etc ...
                                   #^ xticlabels (apparently) come last.

擬似列 0 に慣れていない場合、これは (本質的に) データファイルの行番号です。私は通常、これらの出力を投稿しませんが、これは 1 つの非常にカラフルなプロットになります!

カラフルな棒グラフ

于 2012-07-26T12:46:34.197 に答える
1

何かを編集するだけで、機能するようになりました。

set boxwidth 1
set grid
set style fill solid 1.0 border -1
set yrange [0:*]
set xrange [-.5:*]
set xtics border in scale 0,10  nomirror rotate by -45 left
plot "histo.dat" using ($0):1:($2):xticlabels(3) w boxes lc rgb variable notitle
                        #^boxes centered on 0,1,2,3,....
                           #^data column
                              #^ linecolor column.  first box has linecolor corresponding to ls 0, second box has linecolor corresponding to ls 1, etc ...
                                   #^ xticlabels (apparently) come last.
于 2012-07-31T17:44:01.570 に答える