1

外部コマンドを実行してそれを個別にrtmpdump読み取りたいのですが、そのようなコマンドが終了するまで待たずに、利用可能な場合は部分的な出力をまとめて読み取ります...STDOUTSTDERR

Perlでそれを行う安全な方法は何ですか?

これは、「行ごと」に機能するコードです。

#!/usr/bin/perl

use warnings;
use strict;
use Symbol;
use IPC::Open3;
use IO::Select;

sub execute {
  my($cmd) = @_;
  print "[COMMAND]: $cmd\n";
  my $pid = open3(my $in, my $out, my $err = gensym(), $cmd);
  print "[PID]: $pid\n";
  my $sel = new IO::Select;
  $sel->add($out, $err);
  while(my @fhs = $sel->can_read) {
    foreach my $fh (@fhs) {
      my $line = <$fh>;
      unless(defined $line) {
        $sel->remove($fh);
        next;
      }
      if($fh == $out) {
        print "[OUTPUT]: $line";
      } elsif($fh == $err) {
        print "[ERROR] : $line";
      } else {
        die "[ERROR]: This should never execute!";
      }
    }
  }
  waitpid($pid, 0);
}

しかし、上記のコードはテキスト モードでのみ機能すると思います。コマンドとして使用するには、バイナリ モードで部分的な出力を収集する必要があるため、上記のコードのように行rtmpdumpごとに読み取らないでください。STDOUT

STDOUT のバイナリ出力は、印刷ではなく、変数に格納する必要があります。

4

2 に答える 2

1

ループ内でブロッキング関数 (例readline: <>、readなど) を使用すると、 の使用が妨げられます。selectselect

$sel->add($out, $err);

my %bufs;
while ($sel->count) {
   for my $fh ($sel->can_read) {
      my $rv = sysread($fh, $bufs{$fh}, 128*1024, length($bufs{$fh}));

      if (!defined($rv)) {
         # Error
         die $! ;
      }

      if (!$rv) {
         # Eof
         $sel->remove($fh);
         next;
      }        

      if ($fh == $err) {
         while ($bufs{$err} =~ s/^(.*\n)//) {
            print "[ERROR] $1";
         }
      }
   }
}

print "[ERROR] $bufs{$err}\n" if length($bufs{$err});

waitpid($pid, 0);

... do something with $bufs{$out} ...

しかし、 IPC::Runを使用する方がはるかに簡単です。

use IPC::Run qw( run );

my ($out_buf, $err_buf);
run [ 'sh', '-c', $cmd ],
   '>', \$out_buf, 
   '2>', sub {
      $err_buf .= $_[0];
      while ($err_buf =~ s/^(.*\n)//) {
         print "[ERROR] $1";
      }
   };

print "[ERROR] $err_buf\n" if length($err_buf);

... do something with $out_buf ...
于 2013-06-20T18:01:43.920 に答える