1

次のコードがあるとします。

<database>
    <table name="table1">
       <column name="id"/>
       <column name="created_at"/>
    </table>
    <table name="table2">
       <column name="id"/>
       <column name="updated_at"/>
    </table>
</database>

特定のテーブルに名前で特定の列がある場合、xsl:key を使用してテストできるようにしたいと考えています。たとえば、テーブルに「created_at」列があるかどうかを知りたいので、変換内に特定のコードを記述できます。

テーブルに名前で指定された列があるかどうかをテストする一般的なキーを取得しましたが、変換が現在処理されているテーブルに固有のものにする方法がわかりません。

    <xsl:key name="columnTest" match="column" use="@name"/>
 <xsl:for-each select="database/table">   
    <xsl:choose>
       <xsl:when test="key('columnTest', 'created_at')">
          <xsl:text>true</xsl:text>
       </xsl:when>
       <xsl:otherwise>
          <xsl:text>false</xsl:text>
       </xsl:otherwise>
    </xsl:choose>
</xsl:for-each>

したがって、すべてのテーブルで「true」になります。任意のガイダンスをいただければ幸いです。

4

1 に答える 1

1

次の変換は、これを行う方法を示しています。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output method="text"/>

 <xsl:key name="kTableByName"
  match="table" use="@name"/>

 <xsl:key name="kColumnByTable"
  match="column" use="concat(generate-id(..), '+', @name)"/>

 <xsl:template match="/">
  <xsl:value-of select=
   "boolean(key('kColumnByTable',
                 concat(generate-id(key('kTableByName', 'table1')),
                        '+',
                        'created_at'
                       )
               )
            )
   "/>

  <xsl:text>&#xA;</xsl:text>

  <xsl:value-of select=
   "boolean(key('kColumnByTable',
                 concat(generate-id(key('kTableByName', 'table1')),
                        '+',
                        'updated_at'
                       )
               )
            )
   "/>
 </xsl:template>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、必要な正しい結果が生成されます。

true
false
于 2010-05-27T21:36:54.790 に答える