3

swfaddressまたはスクリプトを実際に作成して、Flashがブラウザに表示されるURLを（実際に新しいページに切り替えることなく）私が選択したものに変更できるようにすることは可能ですか? swfaddress は、元の swf ファイルを常に参照するように URL を作成することを認識していますが、これは素晴らしいことですが、私が取り組んでいる Web テンプレートでは、サイトでどの URL にアクセスしても、常に swf が読み込まれます。違いは、すぐに読み込まれるコンテンツです。フラッシュを介して別の記事に移動するときに、URL を記事の URL に変更して、あたかもそれが HTML ページであるかのように変更できるようにしたいと考えています。これは、SEO 目的で一致する HTML コンテンツを用意するためです。これは大規模なサイトになり、共有と検索可能性のために最適化したいと考えています.

例として、「site.com/#/news-just-in」ではなく、「site.com/2011/3/news-just-in」の URL が必要です。

これは可能ですか？

4

2 に答える 2

5

これは可能ですが、新しいHTML5 History APIをサポートするブラウザーでのみ可能です。ExternalInterfaceJavaScript レイヤーと連携するには、を使用する必要があります。Flash 側は次のようになります。

package {
  import flash.display.Sprite;
  import flash.events.MouseEvent;
  import flash.external.ExternalInterface;
  import flash.text.TextField;
  import flash.text.TextFieldAutoSize;

  public class Test extends Sprite {
    protected var _text:TextField;

    function Test() {
      var b:Sprite = new Sprite;
      b.graphics.beginFill(0xff0000);
      b.graphics.drawRect(0, 0, 32, 32);
      b.graphics.endFill();
      b.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent):void {
        pushState('/test/foo');
      });
      addChild(b);

      b = new Sprite;
      b.x = 64;
      b.graphics.beginFill(0x0000ff);
      b.graphics.drawRect(0, 0, 32, 32);
      b.graphics.endFill();
      b.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent):void {
        pushState('/test/bar');
      });
      addChild(b);

      _text = new TextField();
      _text.autoSize = TextFieldAutoSize.LEFT;
      _text.y = 64;
      addChild(_text);

      if (ExternalInterface.available) {
        ExternalInterface.addCallback('onPopState', onPopState);
        ExternalInterface.call('test.onReady');
      } else {
        _text.text = 'external interface not available';
      }
    }

    protected function onPopState(path:String):void {
      _text.appendText("flash onPopState: " + path + "\n");
    }

    protected function pushState(path:String):void {
      _text.appendText("flash pushState: " + path + "\n");
      ExternalInterface.call('history.pushState', null, null, path);
    }
  }
}

JavaScript 側は次のようになります。

<!DOCTYPE html>
<html>

<body>
  <script type="text/javascript">
  if (!!(window.history && history.pushState)) {
    var test = {
      onPopState: function(event) {
        if (this.embed) {
          this.embed.onPopState(location.pathname);
        }
      },

      onReady: function() {
        var embed = document.getElementById('flash');
        this.embed = embed.getElementsByTagName('object')[0] || embed;
        this.embed.onPopState(location.pathname);
      }
    };

    window.addEventListener('popstate', function(event) {
      test.onPopState(event);
    }, false);
  } else {
    alert('This browser does not support the history API');
  }
  </script>
  <object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000"
          id="flash" width="780" height="420">
    <param name="movie" value="test.swf" />
    <!--[if !IE]>-->
    <object type="application/x-shockwave-flash"
            data="test.swf" width="780" height="420">
    <!--<![endif]-->
      <p>Flash is required</p>
    <!--[if !IE]>-->
    </object>
    <!--<![endif]-->
  </object>
</body>

</html>

この例でonPopStateは、パスが変更されるたびにpushStateが呼び出され、URL を変更するために呼び出されます。例の赤と青のボックスをクリックして、URL を Flash から変更できます。

これを行い、古いブラウザーをサポートする必要がある場合は、履歴 API がサポートされていないときにハッシュ タグにフォールバックする必要があります。理想的には、これを JS レイヤーで抽象化して、Flash コードがどちらが使用されているかを知る必要がないようにすることができます。このような場合は、 History.jsなどのサードパーティ ライブラリを使用することをお勧めします。これは、ハッシュ フォールバックを処理してくれるからです。

于 2011-03-15T05:03:10.537 に答える
0

ハッシュタグを好きなように変更できますが、意図したとおりに機能させるには定数文字または文字列が必要です。

/*
Provides the deep linking value without the query string.
*/
public static function getPath():String {
    var value:String = SWFAddress.getValue();
    if (value.indexOf('?') != -1) {
        return value.split('?')[0];
    } else if (value.indexOf('#') != -1) {
        return value.split('#')[0];
    } else {
        return value;
    }

また、 SWFAddress.jsおよびSWFAddressOptimizer.js内の「#」のすべてのインスタンスを、新しい文字または文字列の値と一致するように変更する必要があります。

この値を変更することは推奨されておらず、単純な値 (「3」など) に置き換えると問題が発生する可能性があることに注意してください。

于 2011-03-15T03:12:09.030 に答える