5

これが私のコードです：

type
  TForm1 = class(TForm)
    WebBrowser1: TWebBrowser;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;

implementation
uses ActiveX;

procedure TForm1.Button1Click(Sender: TObject); // method 1
var
  HtmlFile: string;
begin
  HtmlFile := ExtractFilePath(Application.ExeName) + 'test.html';
  WebBrowser1.Navigate(HtmlFile);
end;

procedure LoadHtml(wb: TWebBrowser; HTMLStr: string);
var
  aStream: TMemoryStream;
begin
  wb.Navigate('about:blank'); // reset the webbrowser
  while wb.ReadyState < READYSTATE_INTERACTIVE do // wait to load the empty page
    Application.ProcessMessages;
  if Assigned(wb.Document) then
  begin
    aStream := TMemoryStream.Create;
    try
      aStream.WriteBuffer(Pointer(HTMLStr)^, Length(HTMLStr));
      aStream.Seek(0, soFromBeginning);
      (wb.Document as IPersistStreamInit).Load(TStreamAdapter.Create(aStream));
    finally
      aStream.Free;
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject); // method 2
begin
  LoadHtml(WebBrowser1,
    '<html><head></head><body>'+
    '  <object width="640" height="390"> '+
    '  <param name="movie" value="http://www.youtube.com/v/L7NWdxFAHdY&hl=en_US&feature=player_embedded&version=3"> '+
    '  </param><param name="allowFullScreen" value="true"> '+
    '  </param><param name="allowScriptAccess" value="always"> '+
    '  </param><embed src="http://www.youtube.com/v/L7NWdxFAHdY&hl=en_US&feature=player_embedded&version=3" type="application/x-shockwave-flash" allowfullscreen="true" allowScriptAccess="always" width="640" height="390"> '+
    '  </embed></object> '+
    '</body></html>'
    );
end;

test.html

<object width="425" height="349">
<param name="movie" value="http://www.youtube.com/v/1hPxGmTGarM?version=3&amp;hl=iw_IL">
</param><param name="allowFullScreen" value="true"></param>
<param name="allowscriptaccess" value="always"></param>
<embed src="http://www.youtube.com/v/1hPxGmTGarM?version=3&amp;hl=iw_IL" type="application/x-shockwave-flash" width="425" height="349" allowscriptaccess="always" allowfullscreen="true">
</embed></object>

私のアプリケーションは両方の方法でクラッシュします。未処理のwin32例外が発生します（Flashプレーヤーが原因Exception EInvalidOp in module Flash10u.ocx at 00108657. Invalid floating point operation）。

  • このコードをD5、D7、D9で試しました。
  • SHDocVw.dllを再インポートしようとしました。
  • また、TWebBroserの代わりにEmbeddedWBコントロールを使用しようとしました...
  • Internet Explorer / Avant / Maxthonは、このHTMLに問題はありません（すべてIE ActiveXに基づいています）。

何か提案や修正はありますか？

このエラーをキャッチしたり、抑制したりするにはどうすればよいですか？

TWebBrowserイベントを介してその場でHTMLを操作または変更する方法はありますか？Ad-Blockersが機能するのと同じように、Flashプレーヤーの代わりに画像を表示できますか？（私の顧客はインターネット上のサイトにそのコードを持っており、私のDelphiアプリケーションは高速プレビューを提供します）

アップデート

TTimerを使用してFPUを有効/無効にしました（Arjenのアイデアに基づく）：

function Get8087CW: Word; // for D5
asm
        PUSH    0
        FNSTCW  [ESP].Word
        POP     EAX
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
  Timer1.Interval := 5000; // 5 sec
  Saved8087CW := Get8087CW;
end;

procedure TForm1.WebBrowser1BeforeNavigate2(Sender: TObject;
  const pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
  Headers: OleVariant; var Cancel: WordBool);
begin
  Timer1.Enabled := False;
  System.Set8087CW($133F); // Disable all fpu exceptions
end;

procedure TForm1.WebBrowser1DocumentComplete(Sender: TObject;
  const pDisp: IDispatch; var URL: OleVariant);
begin
   Timer1.Enabled := True;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  Set8087CW(Saved8087CW);
end;

更新（2）

アプリケーションの起動時にFPU例外をマスクすることになりました。それ以来、私のアプリケーションに（既知の）影響はありませんでした。

4

2 に答える 2

5

もう少し美しい解決策：

Math.SetExceptionMask([exInvalidOp, exDenormalized, exZeroDivide, exOverflow,
  exUnderflow, exPrecision]);

ドキュメントを正しく読んだ場合、言及されているすべての例外Math.SetExceptionMaskを黙らせます。

ただし、@Arjenのアプローチのよりクリーンで美しいバージョンです。

于 2011-11-20T14:45:55.787 に答える
4

Set8087CW（0x133f）;を使用してFPU例外を一時的に無効にしてみてください。 情報

于 2011-11-20T10:38:33.157 に答える